Capture System ABENDS

An ESTAE routine can be used to intercept System ABENDS, but if the program is executing in AR (Address Register) Mode then ESTAEX should be used instead..

The example opposite illustrates the use of an ESTAE which determines if an S013 has occurred, and provides diagnostic information on the S013INFO DD statement. The information provided is; BLKSIZE, LRECL and RECFM which may assist in determining which piece of information might be missing.

//S0010    EXEC PGM=IEFBR14                                             
//INDD     DD   DSN=&SYSUID..INPUT.DATA,DISP=(,CATLG),                  
//             SPACE=(TRK,5),RECFM=F                                    
//S0020    EXEC PROC=ASMACLG                                            
//C.SYSLIB DD                                                           
//         DD   DISP=SHR,DSN=&SYSUID..JCL.CNTL                          
//C.SYSIN  DD   *                                                       
         PRINT NOGEN                                                    
         TITLE 'M02EX3 - DEMONSTRATES USE OF A ESTAE ROUTINE.'          
M02EX3   CSECT                                                          
         USING *,R15              INITIAL BASE REGISTER                 
BEGIN    B     START                                                    
         DC    AL1(8),CL8'M02EX3' PROGRAM NAME FOR DEBUGGING            
*--------M-Y----S-A-V-E----A-R-E-A------------------------------*       
SAVEAREA DS    F                  RESERVED FOR PLI              *       
PRESAVE  DC    XL8'0'             ADDR OF PREVIOUS SAVE AREA    *       
NEXTSAVE DC    XL8'0'             ADDR OF NEXT SAVE AREA        *       
SREG14   DC    XL8'0'             GENERAL                       *       
SREG15   DC    XL8'0'                     PURPOSE               *       
SREG0    DC    13XL8'0'                           REGISTER SAVE *       
SAVEEND  DS    0H                                               *       
*--------E-N-D----O-F----S-A-V-E----A-R-E-A---------------------*       
         DROP  R15                DUMP INITIAL BASE REGISTER            
START    STM   R14,R12,12(R13)    SAVE THE REGISTERS ON ENTRY.          
         LR    R12,R15            SET UP MY                             
         USING BEGIN,R12                    BASE REGISTER               
         ST    R13,PRESAVE        PERFORM SAVE                          
         LA    R15,SAVEAREA                    AREA                     
         ST    R15,8(R13)                           CHAINING            
         LR    R13,R15            R13 = ADDR OF MY SAVE AREA.           
         L     R11,=V(M02STAE)          SET UP AND TRAP                 
         ESTAE (R11),CT,PARAM=STAEPARM                                  
         OPEN  (INDCB,INPUT,OUTDCB,OUTPUT)  OPEN THE FILES.             
READREC  GET   INDCB,INAREA       READ A RECORD                         
         MVC   OUTAREA1+1(L'INAREA),INAREA COPY INPUT TO PRINT LINE     
         PUT   OUTDCB,OUTAREA1                                          
         PACK  WORK,INAMNT        PACK THE INPUT AMOUNT                 
         AP    ACCUM,WORK         ACCUMULATE TOTAL                      
         B     READREC            REPEAT TILL EXHAUSTED.                
READDONE ED    PTOTAL,WORK        CONVERT TOTAL                         
         PUT   OUTDCB,OUTAREA2                 AND PRINT IT.            
         CLOSE (INDCB,,OUTDCB)                                          
         L     R13,PRESAVE        R13 = PREVIOUS SAVE AREA ADDR.        
         RETURN (14,12),RC=0      RESTORE REGISTERS                     
         LTORG                                                          
INDCB    DCB   MACRF=GM,EODAD=READDONE,DDNAME=INDD,DSORG=PS             
*--------M-Y----I-N-P-U-T----A-R-E-A----------------------*             
INAREA   DS    0CL80                                      *             
INNAME   DS    CL8                FORENAME                *             
         DS    CL1                                        *             
INAMNT   DS    CL2                PERSONAL FEE            *             
         DS    CL69                                       *             
*--------E-N-D----O-F----I-N-P-U-T----A-R-E-A-------------*             
OUTDCB   DCB   MACRF=PM,DDNAME=OUTDD,DSORG=PS                           
OUTAREA1 DC    CL133' '                                                 
*--------M-Y----O-U-T-P-U-T----A-R-E-A--------------------*             
OUTAREA2 DS    0CL133                                     *             
         DC    CL1'0'                                     *             
         DC    C'ACCUMULATED TOTAL IS: '                  *             
PTOTAL   DC    XL3'40202021'                              *             
         DC    CL106' '                                   *             
*--------E-N-D----O-F----O-U-T-P-U-T----A-R-E-A-----------*             
*--------I----S-P-Y----W-I-T-H----M-Y----L-I-T-T-L-E----E-Y-E----*      
STAEPARM DS    0F                 INFO OF USE TO ESTAE ROUTINE   *      
         DC    AL4(INDCB)         STORAGE                        *      
FOOTFALL DS    0C                 END OF PARAMETER LIST          *      
*--------E-N-D----O-F----S-P-I-E----I-N-F-O-R-M-A-T-I-O-N--------*      
WORK     DS    PL2                COVERSION AREA                        
ACCUM    DS    PL2'0'             ACCUMULATED TOTAL (PACKED FORM)       
*----------------------------------------------------------------*      
*        END OF M02EX3 CSECT. THE ESTAE BEGINS BELOW.            *      
*----------------------------------------------------------------*      
M02STAE  CSECT                                                          
         USING *,R15              INITIAL BASE REGISTER                 
BEGIN2   B     BEGSTAE                                                  
         DC    AL1(8),CL8'M02STAE'      PROGRAM NAME FOR DEBUGGING      
*--------M-Y----S-A-V-E----A-R-E-A------------------------------*       
SAVEA    DS    F                  RESERVED FOR PLI              *       
PRESAVE2 DC    XL8'0'             ADDR OF PREVIOUS SAVE AREA    *       
         DC    XL8'0'             ADDR OF NEXT SAVE AREA        *       
         DC    XL8'0'             GENERAL                       *       
         DC    XL8'0'                     PURPOSE               *       
         DC    13XL8'0'                           REGISTER SAVE *       
SAVEAEND DS    0H                                               *       
*--------E-N-D----O-F----S-A-V-E----A-R-E-A---------------------*       
*---------------------------------------------------------------*       
*        REGISTERS ON ENTRY TO STAE ROUTINE ARE:                *       
*              R0  - USED AS A WORK REGISTER BY THE SYSTEM      *       
*              R1  - ADDRESS OF THE PIE OR EPIE FOR THE TASK    *       
*                    THAT CAUSE THE INTERRUPTION                *       
*              R14 - RETURN ADDRESS                             *       
*              R15 - ADDRESS OF THE EXIT ROUTINE                *       
*              ALL OTHER REGISTERS ARE UNCHANGED                *       
*---------------------------------------------------------------*       
         DROP  R15                DUMP INITIAL BASE REGISTER            		 
BEGSTAE  STM   R14,R12,12(R13)    SAVE THE REGISTERS ON ENTRY.          
         LR    R12,R15            SET UP MY                             
         USING BEGIN2,R12                   BASE REGISTER               
         ST    R13,PRESAVE2       PERFORM SAVE                          
         LA    R15,SAVEA                       AREA                     
         ST    R15,8(R13)                           CHAINING            
         LR    R13,R15            R13 = ADDR OF MY SAVE AREA.           
*---------------------------------------------------------------------* 
*        On entry with SDWA:                                          * 
*        R0  = The I/O processing code.                               * 
*        R1  = SDWA address                                           * 
*        R2  = Parameter list address.                                * 
*        On entry without an SDWA:                                    * 
*        R0  = X'0C' indicating no SDWA.                              * 
*        R1  = System ABEND Code                                      * 
*        R2  = Parameter list address.                                * 
*---------------------------------------------------------------------* 
         CH    R0,=H'12'          IS THERE AN SDWA?                     
         BE    NOSDWA             NO  CANNOT HELP THEN.                 
         LR    R10,R1             MAKE SDWA                             
         USING SDWA,R10                     ADDRESSABLE                 
         SR    R15,R15            ISOLATE                               
         ICM   R15,7,SDWACMPC             SYSTEM                        
         SRL   R15,12                            ABEND CODE             
         B     CHCK013            GO CHECK FOR S013                     
NOSDWA   LR    R15,R1             R15 = THIS ABEND CODE                 
CHCK013  CH    R15,=X'0013'       IS IT S013 ABEND?                     
         BNE   NOT013             NO  - CANNOT HELP THEN                
         L     R3,0(R2)           INPUT DCB ADDRESS and                 
         USING IHADCB,R3          MAKE FIELDS ADDRESSABLE               
         LH    R15,DCBBLKSI       CONVERT                               
         CVD   R15,DWORD                                                
         MVC   PBLKSIZE,=X'2020202120'                                  
         ED    PBLKSIZE-1(L'PBLKSIZE+1),DECFLD                          
         LH    R15,DCBLRECL       CONVERT                               
         CVD   R15,DWORD                                                
         MVC   PLRECL,=X'2020202120'                                    
         ED    PLRECL-1(L'PLRECL+1),DECFLD                              
         TM    DCBRECFM,DCBRECU   IS IT UNDEFINED?                      
         BNO   CHCKFIX            NO - CHECK FOR RECFM=F                
         MVI   PRECFM,C'U'        INDICATE RECFM=U                      
         B     NOTIFY                                                   
CHCKFIX  TM    DCBRECFM,DCBRECF   IS IT RECFM=F?                        
         BNO   CHCKVAR            NO - CHECK FOR RECFM=V                
         MVI   PRECFM,C'F'        INDICATE RECFM=F                      
         B     CHCKBLK                                                  
CHCKVAR  MVI   PRECFM,C'V'        INDICATE RECFM=V                      
CHCKBLK  TM    DCBRECFM,DCBRECBR  ARE RECORDS BLOCKED?                  
         BNO   CHCKCCA            NO - CHECK FOR CONTROL CHAR           
         MVI   PRECFM+1,C'B'      INDICATE RECFM=xB                     
         TM    DCBRECFM,DCBRECSB  DOES RECFM=S APPLY?                   
         BNO   CHCKCCA            NO - CHECK FOR ASA CONTROL            
         MVI   PRECFM+2,C'S'      INDICATE RECFM=xBS                    
CHCKCCA  TM    DCBRECFM,DCBRECCA  IS THERE ASA CONTROL                  
         BNO   CHCKCCM            NO - CHECK FOR MACHINE CONTROL        
         MVI   PRECFM+2,C'A'      INDICATE RECFM=xBA                    
         B     NOTIFY                                                   
CHCKCCM  TM    DCBRECFM,DCBRECCM  IS THERE MACHINE CONTROL              
         BNO   NOTIFY             NO - THEN REPORT FINDINGS             
         MVI   PRECFM+2,C'M'      INDICATE RECFM=xBM                    
NOTIFY   OPEN  (DIAGINFO,OUTPUT)  OPEN DIAGNOSTIC FILE                  
         PUT   DIAGINFO,MSG1      WRITE FIRST MESSAGE                   
         PUT   DIAGINFO,MSG2      REPORT BLKSIZE                        
         PUT   DIAGINFO,MSG3      REPORT LRECL                          
         PUT   DIAGINFO,MSG4      REPORT RECFM                          
QUIT     CLOSE DIAGINFO                                                 
NOT013   L     R13,PRESAVE2       R13 = PREVIOUS SAVE AREA ADDR.        
         RETURN (14,12)           RESTORE REGISTERS                     
         LTORG                                                          
DWORD    DS    D                  DECIMAL CONVERSION WORK AREA          
         ORG   DWORD+5                                                  
DECFLD   DS    XL3                DECIMAL FORMAT DATA                   
         ORG   ,                                                        
DIAGINFO DCB   DSORG=PS,MACRF=(PM),DDNAME=S013INFO,RECFM=F,LRECL=121    
MSG1     DC    CL121'1 OPEN Failed S013'                                
MSG2     DC    CL121'0 BLKSIZE = '                                      		 
         ORG   MSG2+13                                                  
PBLKSIZE DS    CL5                                                      
         ORG   ,                                                        
MSG3     DC    CL121'0 LRECL   = '                                      
         ORG   MSG3+13                                                  
PLRECL   DS    CL5                                                      
         ORG   ,                                                        
MSG4     DC    CL121'0 RECFM   = '                                      
         ORG   MSG4+13                                                  
PRECFM   DS    CL3                                                      
         ORG   ,                                                        
         DCBD  DSORG=PS                                                 
         IHASDWA                                                        
         COPY  REGS                                                     
         END   ,                  PHYSICAL END OF THE PROGRAM           
//G.OUTDD    DD SYSOUT=*,RECFM=FBA,LRECL=133                            
//G.S013INFO DD SYSOUT=*                                                
//G.INDD     DD DSN=&SYSUID..INPUT.DATA,DISP=(OLD,DELETE)