Capture Program Interrupts

This is the mnemonic for Exit Programs which facilitate the trapping of Program Interrupts. The original 24-bit versions was SPIE, which with the advent of 31-bit addressing has become ESPIE.

ESTAE exits could also be used to trap Program Interrupts. but ESPIE is more efficient especially if other ABEND types are not of interest.

In the example opposite the ESPIE Macro is set to intercept 0C7 conditions only, and the exit issues U0240 REASON 000000C7 as well as printing the related storage area on DD statement DIAGINFO if a Data Exception occurs.

//S0010    EXEC PROC=ASMACLG                                     
//C.SYSLIB DD                                                    
//         DD   DISP=SHR,DSN=&SYSUID..JCL.CNTL                   
//C.SYSIN  DD   *                                                
         PRINT NOGEN                                             
         TITLE 'M02EX3 - DEMONSTRATES USE OF A ESPIE ROUTINE.'   
M02EX3   CSECT                                                   
         USING *,R15              INITIAL BASE REGISTER          
BEGIN    B     START                                             
         DC    AL1(8),CL8'M02EX3' PROGRAM NAME FOR DEBUGGING     
*--------M-Y----S-A-V-E----A-R-E-A------------------------------*
SAVEAREA DS    F                  RESERVED FOR PLI              *
PRESAVE  DC    XL8'0'             ADDR OF PREVIOUS SAVE AREA    *
NEXTSAVE DC    XL8'0'             ADDR OF NEXT SAVE AREA        *
SREG14   DC    XL8'0'             GENERAL                       *
SREG15   DC    XL8'0'                     PURPOSE               *
SREG0    DC    13XL8'0'                           REGISTER SAVE *
SAVEEND  DS    0H                                               *
*--------E-N-D----O-F----S-A-V-E----A-R-E-A---------------------*
         DROP  R15                DUMP INITIAL BASE REGISTER     
START    STM   R14,R12,12(R13)    SAVE THE REGISTERS ON ENTRY.          
         LR    R12,R15            SET UP MY                             
         USING BEGIN,R12                    BASE REGISTER               
         ST    R13,PRESAVE        PERFORM SAVE                          
         LA    R15,SAVEAREA                    AREA                     
         ST    R15,8(R13)                           CHAINING            
         LR    R13,R15            R13 = ADDR OF MY SAVE AREA.           
         ST    R12,SAVEDEP                                              
         L     R11,=V(M02SPIE)          SET UP AND TRAP                 
         ESPIE SET,(R11),(7),PARAM=SPIEPARM                             
         ST    R1,TOKEN                 SAVE ESPIE TOKEN                
         OPEN  (INDCB,INPUT,OUTDCB,OUTPUT)  OPEN THE FILES.             
READREC  GET   INDCB,INAREA       READ A RECORD                         
         MVC   OUTAREA1+1(L'INAREA),INAREA COPY INPUT TO PRINT LINE     
         PUT   OUTDCB,OUTAREA1                                          
         PACK  WORK,INAMNT        PACK THE INPUT AMOUNT                 
         AP    ACCUM,WORK         ACCUMULATE TOTAL                      
         B     READREC            REPEAT TILL EXHAUSTED.                
READDONE ED    PTOTAL,WORK        CONVERT TOTAL                         
         PUT   OUTDCB,OUTAREA2                 AND PRINT IT.            
         CLOSE (INDCB,,OUTDCB)                                          
         L     R13,PRESAVE        R13 = PREVIOUS SAVE AREA ADDR.        
         RETURN (14,12),RC=0      RESTORE REGISTERS                     
         LTORG                                                          
TOKEN    DS    F                  TOKEN RETURN BY Z/OS FOR ESPIE        
INDCB    DCB   MACRF=GM,EODAD=READDONE,DDNAME=INDD,DSORG=PS             
*--------M-Y----I-N-P-U-T----A-R-E-A----------------------*             
INAREA   DS    0CL80                                      *             
INNAME   DS    CL8                FORENAME                *             
         DS    CL1                                        *             
INAMNT   DS    CL2                PERSONAL FEE            *             
         DS    CL69                                       *             
*--------E-N-D----O-F----I-N-P-U-T----A-R-E-A-------------*             
OUTDCB   DCB   MACRF=PM,DDNAME=OUTDD,DSORG=PS                           
OUTAREA1 DC    CL133' '                                                 
*--------M-Y----O-U-T-P-U-T----A-R-E-A--------------------*             
OUTAREA2 DS    0CL133                                     *             
         DC    CL1'0'                                     *             
         DC    C'ACCUMULATED TOTAL IS: '                  *             
PTOTAL   DC    XL3'40202021'                              *             
         DC    CL106' '                                   *             
*--------E-N-D----O-F----O-U-T-P-U-T----A-R-E-A-----------*             
*--------I----S-P-I-E----W-I-T-H----M-Y----L-I-T-T-L-E----E-Y-E--*      
SPIEPARM DS    0F                 INFO OF USE TO ESPIE ROUTINE   *      
         DC    AL4(INAREA)        STORAGE                        *      
         DC    AL4(INAREA+80)            AREAS                   *      
         DC    AL4(SAVEDEP)                   OF                 *      
         DC    AL4(SAVEDEP+15)                  INTEREST         *      
FOOTFALL DC    AL1(*-*)           FOOTPRINT                      *      
*--------E-N-D----O-F----S-P-I-E----I-N-F-O-R-M-A-T-I-O-N--------*      
SAVEDEP  DS    F                                                        
WORK     DS    PL2                COVERSION AREA                        
ACCUM    DS    PL2'0'             ACCUMULATED TOTAL (PACKED FORM)       
*----------------------------------------------------------------*      
*        END OF M02EX3 CSECT. THE ESPIE BEGINS BELOW.            *      
*----------------------------------------------------------------*      
M02SPIE  CSECT                                                          
         USING *,R15              INITIAL BASE REGISTER                 
BEGIN2   B     BEGSPIE                                                  
         DC    AL1(8),CL8'M02SPIE'      PROGRAM NAME FOR DEBUGGING      
*--------M-Y----S-A-V-E----A-R-E-A------------------------------*       
SAVEA    DS    F                  RESERVED FOR PLI              *       
PRESAVE2 DC    XL8'0'             ADDR OF PREVIOUS SAVE AREA    *       
         DC    XL8'0'             ADDR OF NEXT SAVE AREA        *       
         DC    XL8'0'             GENERAL                       *       
         DC    XL8'0'                     PURPOSE               *       
         DC    13XL8'0'                           REGISTER SAVE *       
SAVEAEND DS    0H                                               *       
*--------E-N-D----O-F----S-A-V-E----A-R-E-A---------------------*       
*---------------------------------------------------------------*       
*        REGISTERS ON ENTRY TO SPIE ROUTINE ARE:                *       
*              R0  - USED AS A WORK REGISTER BY THE SYSTEM      *       
*              R1  - ADDRESS OF THE PIE OR EPIE FOR THE TASK    *       
*                    THAT CAUSE THE INTERRUPTION                *       
*              R14 - RETURN ADDRESS                             *       
*              R15 - ADDRESS OF THE EXIT ROUTINE                *       
*              ALL OTHER REGISTERS ARE UNCHANGED                *       
*---------------------------------------------------------------*       
         DROP  R15                DUMP INITIAL BASE REGISTER            
BEGSPIE  STM   R14,R12,12(R13)    SAVE THE REGISTERS ON ENTRY.          
         LR    R12,R15            SET UP MY                             
         USING BEGIN2,R12                   BASE REGISTER               
         ST    R13,PRESAVE2       PERFORM SAVE                          
         LA    R15,SAVEA                       AREA                     
         ST    R15,8(R13)                           CHAINING            
         LR    R13,R15            R13 = ADDR OF MY SAVE AREA.           
         LR    R10,R1             MAKE EPIE                             
         USING EPIE,R10                     ADDRESSABLE                 
         L     R4,EPIEPARM        OBTAIN PARAMETER LIST ADDRESS         
         OC    REASON,EPIEICD1    CAPTURE PROGRAM INTERRUPT CODE        
         WTO   'M02SPIE - The REASON CODE indicates the Exception',    *
               ROUTCDE=11                                               
         OPEN  (DIAGINFO,OUTPUT)  OPEN DIAGNOSTIC FILE                  
         LM    R2,R3,0(R4)                                              
         USING RECDSECT,R2                                              
         MVZ   ZONEWORK,INNUM     ISOLATE INPUT ZONES                   
         CLC   ZONEWORK,GOODZONE  ARE ZONES OK?                         
         BE    ZONESOK            YES - MOVE ON, ELSE                   
         WTO   'M02SPIE - Input field in error see DIAGLIST',          *
               ROUTCDE=11                                               
         SNAP  DCB=DIAGINFO,STORAGE=((R2),(R3)),STRHDR=HDR1             
         DROP  R2                                                       
ZONESOK  LM    R2,R3,8(R4)                                              
         USING TOTDSECT,R2                                              
         SR    R4,R4                                                    
         IC    R4,ACCTOT+1        ISOLATE                               
         SLL   R4,28                     ACCUM'S                        
         SRL   R4,28                             SIGN                   
         CH    R4,X000A           CHECK THE SIGN, AND                   
         BNL   QUIT               QUIT IF VALID, ELSE SAY NOT           
         WTO   'M02SPIE - Accummulator field is invalid',routcde=11     
         SNAP  DCB=DIAGINFO,STORAGE=((R2),(R3)),STRHDR=HDR2             
QUIT     CLOSE DIAGINFO                                                 
         ICM   R2,15,RCODE        USE PIC                               
         ABEND 240,REASON=(2)            AS REASON CODE                 
DIAGINFO DCB   DSORG=PS,MACRF=W,DDNAME=DIAGLIST                         
RCODE    DC    XL4'000000C0'      REASON CODE VALUE AREA                
         ORG   RCODE+3                                                  
REASON   DS    XL1                PIC VALUE GOES HERE                   
         ORG   ,                                                        
X000A    DC    X'000A'            LOWSET VALID DECIMAL SIGN             
ZONEWORK DC    X'0000'                                                  
GOODZONE DC    X'F0F0'            NORMAL KEYBOARD NUMERIC ZONES         
HDR1     DC    AL1(26),C'** Current input record **'                    
HDR2     DC    AL1(41),C'** ACCUM is the 2 bytes prior to 47F0 **'      
         IHAEPIE                                                        
RECDSECT DSECT                                                          
RECNAME  DS    CL8                                                      
         DS    CL1                                                      
INNUM    DS    CL2                                                      
         DS    CL69                                                     
TOTDSECT DSECT                                                          
         DS    F                                                        
         DS    PL2                                                      
ACCTOT   DS    PL2                                                      
         COPY  REGS                                                     
         END   ,                  PHYSICAL END OF THE PROGRAM           
//G.OUTDD    DD SYSOUT=*,RECFM=FBA,LRECL=133                            
//G.DIAGLIST DD SYSOUT=*,RECFM=VBA,LRECL=125,BLKSIZE=882                
//G.INDD     DD *                                                       
JOHN     10                                                             
PAUL     15                                                             
GEORGE   20                                                             
RINGO    7