COBOL example

Here the name on the ALIAS statement matches the name on the ENTRY statement within the COBOL source code.

This means the program can be executed by either name, but when EPTEST2 is used on the JCL EXEC statement processing begins at the first instruction within the PROCEDURE DIVISION.

When EP4 is used on the JCL EXEC statement processing begins at the instruction after the COBOL ENTRY statement.

//S0010    EXEC PROC=IGYWCL                                             
//COBOL.SYSIN   DD  *                                                   
       IDENTIFICATION DIVISION.                                         
       PROGRAM-ID.                      EPTEST2.                        
       AUTHOR.                          T.R.SAMBROOKS.                  
           INSTALLATION.                                                
           DATE-WRITTEN.                04th August 2021.               
       ENVIRONMENT DIVISION.                                            
       CONFIGURATION SECTION.                                           
      *----------------------------------------------------------------*
      * This program is designed to test the use of ENTRY and ALIAS    *
      * statements.                                                    *
      *----------------------------------------------------------------*
       INPUT-OUTPUT SECTION.                                            
       FILE-CONTROL.                                                    
       DATA DIVISION.                                                   
       FILE SECTION.                                                    
       WORKING-STORAGE SECTION.                                         
       77  ENTRY-FLAG                  PIC 9.                           
       PROCEDURE DIVISION.                                              
       AA-MAIN-PGM SECTION.                                             
           MOVE 1                      TO ENTRY-FLAG.                   
           DISPLAY 'Entry flag ' entry-flag ' means EPTEST2 used.'      
                                       UPON SYSOUT.                     
      *----------------------------------------------------------------*
      * This is the logical end of the source code program - EPTEST2   *
      *----------------------------------------------------------------*
       AA-MAIN-PGM-EOJ.                                                 
           GOBACK.                                                      
       BB-SECONDARY-RTN SECTION.                                        
           ENTRY                       'EP4'.                           
           MOVE 2                      TO ENTRY-FLAG.                   
           DISPLAY 'Entry flag ' entry-flag ' means EP4 used.'          
                                       UPON SYSOUT.                     
      *----------------------------------------------------------------*
      * This is the logical end of the entry point - EP4               *
      *----------------------------------------------------------------*
       BB-SECONDARY-RTN-EXIT.                                              
           GOBACK.                                                      
      *----------------------------------------------------------------*
      * This is the physical end of the source code program - EPTEST2  *
      *----------------------------------------------------------------*
//LKED.SYSIN   DD  *                                                    
 ALIAS EP4                                                              
 NAME EPTEST2(R)                                                        
//LKED.SYSLMOD DD DISP=SHR,DSN=&SYSUID..LINKLIB                         
//S0020    EXEC  PGM=EPTEST2                                            
//STEPLIB  DD    DISP=SHR,DSN=&SYSUID..LINKLIB                          
//S0030    EXEC  PGM=EP4                                                
//STEPLIB  DD    DISP=SHR,DSN=&SYSUID..LINKLIB

The ep_name must comply with program naming rules. If there is no matching ESD entry, the alias becomes an alternative name to that on the NAME statement and processing will start at the main entry point.