Assembler example

Here the name on the ALIAS statement matches the name on the ENTRY statement within the Assembler source code.

This means the program can be executed by either name, but when EPTEST is used on the JCL EXEC statement processing begins at the main entry point, whereas when EP2 is used on the JCL EXEC statement processing begins at the instruction after the Assembler ENTRY statement.

The audio file explains the CSECT statement which has been commented out.

//S0010    EXEC PROC=ASMACL                                            
//SYSIN    DD   *                                                      
EPTEST   CSECT                                                         
         USING *,R15              ESTABLISH INITIAL ADDRESSABILITY.    
CENTRY   B     EP1S               BRANCH AROUND SAVE AREA.             
         DC    AL1(8)             LENGTH OF MODULE NAME.               
         DC    CL8'EPTEST'        MODULE NAME - TO AID DEBUGGING.      
*--------------P-O-S-I-T-I-O-N-A-L-L-Y---D-E-P-E-N-D-A-N-T---C-O-D-E--*
EP1SAVEA DS    0F                 18 FULLWORD REGISTER SAVE AREA.     *
         DC    AL4(0)             RESERVED FOR PL/I                   *
PRESAVE1 DC    AL4(*-*)           PREVIOUS SAVE AREA IN CHAIN.        *
NXTSAVE1 DC    AL4(*-*)           NEXT SAVE AREA IN CHAIN.            *
         DC    15F'0'             REGISTERS 14 THRU 12 GO HERE.       *
SAVEEND1 DS    0H                 END OF THE SAVE AREA.               *
*---------------------------------------------------------------------*
         DROP  15                                                      
EP1S     STM   R14,R12,12(R13)    SAVE THE REGISTERS,                  
         LR    R12,R15              SET UP R12 AS BASE, FROM EP, AND   
         USING CENTRY,R12             ESTABLISH ADDRESSABILITY.        
         ST    R13,PRESAVE1       PERFORM                               
         LA    R15,EP1SAVEA             SAVE                            
         ST    R15,8(R13)                  AREA                         
         LR    R13,R15                        CHAINING.                 
         WTO   'EPTEST - ENTERED AT MAIN CSECT',ROUTCDE=13              
         SPACE 3                                                        
         L     R13,PRESAVE1       RESTORE R13, AND                      
         LM    R14,R12,12(R13)             OTHERS EXCEPT R15.           
         LA    R15,0              SET COND CODE 0000                    
         BR    R14                                                      
         DROP 12                                                        
*EP2      CSECT                                                         
         ENTRY EP2                                                      
EP2      LR    R12,R15                                                  
         USING EP2S,R12           ESTABLISH ADDRESSABILITY.             
EP2S     STM   R14,R12,12(R13)    SAVE THE REGISTERS,                   
         ST    R13,PRESAVE2       PERFORM                               
         LA    R15,EP2SAVEA             SAVE                            
         ST    R15,8(R13)                  AREA                         
         LR    R13,R15                        CHAINING.                
         WTO   'EPTEST - ENTERED AT VIA EP2',ROUTCDE=13                
         L     R13,PRESAVE2       RESTORE R13, AND                     
         LM    R14,R12,12(R13)             OTHERS EXCEPT R15.          
         LA    R15,0              SET COND CODE 0000                   
         BR    R14                                                     
         EJECT                                                         
*--------------P-O-S-I-T-I-O-N-A-L-L-Y---D-E-P-E-N-D-A-N-T---C-O-D-E--*
EP2SAVEA DS    0F                 18 FULLWORD REGISTER SAVE AREA.     *
         DC    AL4(0)             RESERVED FOR PL/I                   *
PRESAVE2 DC    AL4(*-*)           PREVIOUS SAVE AREA IN CHAIN.        *
NXTSAVE2 DC    AL4(*-*)           NEXT SAVE AREA IN CHAIN.            *
         DC    15F'0'             REGISTERS 14 THRU 12 GO HERE.       *
SAVEEND2 DS    0H                 END OF THE SAVE AREA.               *
*---------------------------------------------------------------------*
R12      EQU   12                                                      
R13      EQU   13                                                      
R14      EQU   14                                                      
R15      EQU   15                                                      
         END                                 
//L.SYSIN   DD  *                            
 ALIAS EP2                                   
 NAME EPTEST(R)                              
//L.SYSLMOD DD DISP=SHR,DSN=&SYSUID..LINKLIB   
//S0020    EXEC  PGM=EPTEST                  
//STEPLIB  DD    DISP=SHR,DSN=&SYSUID..LINKLIB 
//S0030    EXEC  PGM=EP2                     
//STEPLIB  DD    DISP=SHR,DSN=&SYSUID..LINKLIB

The ep_name must comply with program naming rules. If there is no matching ESD entry, the alias becomes an alternative name to that on the NAME statement and processing will start at the main entry point.